#
# Parallel axis plot
# shows plot layout but would better use some real data set
#
set title "Parallel Axis Plot" font ",15"

set border 0
unset key
set xrange [] noextend
unset ytics

# Use x-axis tic positions to label the axes
set xtics 1 format "axis %g" scale 0,0

# Turn on axis tics for the parallel axes
set for [i=1:5] ptics i

# Use the range commands to create an "interesting" plot.
# For suitable input data this is the sort of result you
# might get without axis range manipulation.

set prange 2 [0:30]
set prange 4 [-10:50]
set prange 5 [50:*] reverse
set ptics  5 left offset 4

plot 'silver.dat' using 2:3:1:($3/2):2:(int($0/25)) with parallel lt 1 lc variable


Click here for minimal script to generate this plot

set title "Parallel Axis Plot" font ",15"

set border 0
unset ytics
set xtics ("X" 1, "Y" 2, "Z" 3, "B" 4) nomirror 
set xrange [] noextend
unset key

set ptics 1 format '%.0f Å' offset -1
set ptics 4 left offset 4 format '%.0f Å^2'
set prange 4 [0:40]

plot 'GM1_sugar.pdb' using 6:7:8:10:5 with parallel lc var lw 2


Click here for minimal script to generate this plot